From 2fbe4702c57d025271bb48707064a0d09da98be4 Mon Sep 17 00:00:00 2001
From: Alpha Chen <alpha@kejadlen.dev>
Date: Thu, 25 Nov 2021 21:11:52 -0800
Subject: [PATCH] fzf git bindings

https://junegunn.kr/2016/07/fzf-git/
---
 runcoms/zshrc | 83 +++++++++++++++++++++++++++++++++++++++++----------
 1 file changed, 68 insertions(+), 15 deletions(-)

diff --git a/runcoms/zshrc b/runcoms/zshrc
index 6c18801..5938076 100644
--- a/runcoms/zshrc
+++ b/runcoms/zshrc
@@ -73,27 +73,80 @@ if [ $commands[fzf] ]; then
     dir="$(fasd -Rdl "$1" | fzf -1 -0 --no-sort +m)" && cd "${dir}" || return 1
   }
 
-  # CTRL-G
-  __fgit() {
-    local cmd="git status --porcelain | awk '{ print \$2 }'"
-    setopt localoptions pipefail no_aliases 2> /dev/null
+  # https://junegunn.kr/2016/07/fzf-git/
+  is_in_git_repo() {
+    git rev-parse HEAD > /dev/null 2>&1
+  }
+
+  fzf-down() {
+    fzf --height 50% --min-height 20 --border --bind ctrl-/:toggle-preview "$@"
+  }
+
+  _gf() {
+    is_in_git_repo || return
+    git -c color.status=always status --short |
+    fzf-down -m --ansi --nth 2..,.. \
+      --preview '(git diff --color=always -- {-1} | sed 1,4d; cat {-1})' |
+    cut -c4- | sed 's/.* -> //'
+  }
+
+  _gb() {
+    is_in_git_repo || return
+    git branch -a --color=always | grep -v '/HEAD\s' | sort |
+    fzf-down --ansi --multi --tac --preview-window right:70% \
+      --preview 'git log --oneline --graph --date=short --color=always --pretty="format:%C(auto)%cd %h%d %s" $(sed s/^..// <<< {} | cut -d" " -f1)' |
+    sed 's/^..//' | cut -d' ' -f1 |
+    sed 's#^remotes/##'
+  }
+
+  _gt() {
+    is_in_git_repo || return
+    git tag --sort -version:refname |
+    fzf-down --multi --preview-window right:70% \
+      --preview 'git show --color=always {}'
+  }
+
+  _gh() {
+    is_in_git_repo || return
+    git log --date=short --format="%C(green)%C(bold)%cd %C(auto)%h%d %s (%an)" --graph --color=always |
+    fzf-down --ansi --no-sort --reverse --multi --bind 'ctrl-s:toggle-sort' \
+      --header 'Press CTRL-S to toggle sort' \
+      --preview 'grep -o "[a-f0-9]\{7,\}" <<< {} | xargs git show --color=always' |
+    grep -o "[a-f0-9]\{7,\}"
+  }
+
+  _gr() {
+    is_in_git_repo || return
+    git remote -v | awk '{print $1 "\t" $2}' | uniq |
+    fzf-down --tac \
+      --preview 'git log --oneline --graph --date=short --pretty="format:%C(auto)%cd %h%d %s" {1}' |
+    cut -d$'\t' -f1
+  }
+
+  _gs() {
+    is_in_git_repo || return
+    git stash list | fzf-down --reverse -d: --preview 'git show --color=always {1}' |
+    cut -d: -f1
+  }
+
+  join-lines() {
     local item
-    eval "$cmd" | FZF_DEFAULT_OPTS="--height ${FZF_TMUX_HEIGHT:-40%} --reverse $FZF_DEFAULT_OPTS" $(__fzfcmd) -m "$@" | while read item; do
+    while read item; do
       echo -n "${(q)item} "
     done
-    local ret=$?
-    echo
-    return $ret
   }
 
-  fzf-git-widget() {
-    LBUFFER="${LBUFFER}$(__fgit)"
-    local ret=$?
-    zle reset-prompt
-    return $ret
+  bind-git-helper() {
+    local c
+    for c in $@; do
+      eval "fzf-g$c-widget() { local result=\$(_g$c | join-lines); zle reset-prompt; LBUFFER+=\$result }"
+      eval "zle -N fzf-g$c-widget"
+      eval "bindkey '^g$c' fzf-g$c-widget"  # So it works in tmux
+      eval "bindkey '^g^$c' fzf-g$c-widget"
+    done
   }
-  zle     -N   fzf-git-widget
-  bindkey '^G' fzf-git-widget
+  bind-git-helper f b t r h s
+  unset -f bind-git-helper
 fi
 
 if [ $commands[exa] ]; then