From ebad8940fb799a5cf9d045856749904977cd9743 Mon Sep 17 00:00:00 2001
From: Michael Richters <gedankenexperimenter@gmail.com>
Date: Thu, 23 Dec 2021 12:27:42 -0500
Subject: [PATCH] Add testcases for ShiftBlocker example plugin

Signed-off-by: Michael Richters <gedankenexperimenter@gmail.com>
---
 .../Macros/shift-blocker/shift-blocker.ino    | 99 +++++++++++++++++++
 .../plugins/Macros/shift-blocker/sketch.json  |  6 ++
 tests/plugins/Macros/shift-blocker/test.ktest | 55 +++++++++++
 3 files changed, 160 insertions(+)
 create mode 100644 tests/plugins/Macros/shift-blocker/shift-blocker.ino
 create mode 100644 tests/plugins/Macros/shift-blocker/sketch.json
 create mode 100644 tests/plugins/Macros/shift-blocker/test.ktest

diff --git a/tests/plugins/Macros/shift-blocker/shift-blocker.ino b/tests/plugins/Macros/shift-blocker/shift-blocker.ino
new file mode 100644
index 00000000..bcc16998
--- /dev/null
+++ b/tests/plugins/Macros/shift-blocker/shift-blocker.ino
@@ -0,0 +1,99 @@
+/* -*- mode: c++ -*-
+ * Copyright (C) 2021  Keyboard.io, Inc.
+ *
+ * This program is free software: you can redistribute it and/or modify it under
+ * the terms of the GNU General Public License as published by the Free Software
+ * Foundation, version 3.
+ *
+ * This program is distributed in the hope that it will be useful, but WITHOUT
+ * ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
+ * FOR A PARTICULAR PURPOSE. See the GNU General Public License for more
+ * details.
+ *
+ * You should have received a copy of the GNU General Public License along with
+ * this program. If not, see <http://www.gnu.org/licenses/>.
+ */
+
+#include <Kaleidoscope.h>
+#include <Kaleidoscope-Macros.h>
+
+// *INDENT-OFF*
+KEYMAPS(
+  [0] = KEYMAP_STACKED
+  (
+      M(0), ___, ___, ___, ___, ___, ___,
+      Key_LeftShift, ___, ___, ___, ___, ___, ___,
+      ___, ___, ___, ___, ___, ___,
+      ___, ___, ___, ___, ___, ___, ___,
+
+      ___, ___, ___, ___,
+      ___,
+
+      ___, ___, ___, ___, ___, ___, ___,
+      ___, ___, ___, ___, ___, ___, ___,
+           ___, ___, ___, ___, ___, ___,
+      ___, ___, ___, ___, ___, ___, ___,
+
+      ___, ___, ___, ___,
+      ___
+   ),
+)
+// *INDENT-ON*
+
+// ShiftBlocker plugin
+namespace kaleidoscope {
+namespace plugin {
+
+// When activated, this plugin will suppress any `Shift` key (including modifier
+// combos with `Shift`) before it's added to the HID report.
+class ShiftBlocker : public Plugin {
+ public:
+  EventHandlerResult onAddToReport(Key key) {
+    if (active_ && key.isKeyboardShift())
+      return EventHandlerResult::ABORT;
+    return EventHandlerResult::OK;
+  }
+  void enable() {
+    active_ = true;
+  }
+  void disable() {
+    active_ = false;
+  }
+
+ private:
+  bool active_{false};
+};
+
+} // namespace kaleidoscope
+} // namespace plugin
+
+kaleidoscope::plugin::ShiftBlocker ShiftBlocker;
+
+const macro_t *macroAction(uint8_t macro_id, KeyEvent &event) {
+  if (keyToggledOn(event.state)) {
+    switch (macro_id) {
+    case 0:
+      // First, enable ShiftBlocker to suppress any held `Shift` key(s).
+      ShiftBlocker.enable();
+      // Tap `AltGr` + `7` to activate the grave accent dead key.
+      Macros.tap(RALT(Key_7));
+      // Disable ShiftBlocker so it won't affect the `E` event.
+      ShiftBlocker.disable();
+      // Change the Macros key into a plain `E` key before its press event is
+      // processed.
+      event.key = Key_E;
+      break;
+    }
+  }
+  return MACRO_NONE;
+}
+
+KALEIDOSCOPE_INIT_PLUGINS(Macros, ShiftBlocker);
+
+void setup() {
+  Kaleidoscope.setup();
+}
+
+void loop() {
+  Kaleidoscope.loop();
+}
diff --git a/tests/plugins/Macros/shift-blocker/sketch.json b/tests/plugins/Macros/shift-blocker/sketch.json
new file mode 100644
index 00000000..8cc86922
--- /dev/null
+++ b/tests/plugins/Macros/shift-blocker/sketch.json
@@ -0,0 +1,6 @@
+{
+  "cpu": {
+    "fqbn": "keyboardio:virtual:model01",
+    "port": ""
+  }
+}
diff --git a/tests/plugins/Macros/shift-blocker/test.ktest b/tests/plugins/Macros/shift-blocker/test.ktest
new file mode 100644
index 00000000..5ff46482
--- /dev/null
+++ b/tests/plugins/Macros/shift-blocker/test.ktest
@@ -0,0 +1,55 @@
+VERSION 1
+
+KEYSWITCH M_0    0 0
+KEYSWITCH SHIFT  1 0
+
+# ==============================================================================
+NAME Macro without shift
+
+RUN 5 ms
+PRESS M_0
+RUN 1 cycle
+EXPECT keyboard-report Key_RightAlt # Report should contain only `AltGr`
+EXPECT keyboard-report Key_RightAlt Key_7 # Report should contain `AltGr` & `7`
+EXPECT keyboard-report Key_RightAlt # Report should contain only `AltGr`
+EXPECT keyboard-report empty # Report should be empty
+EXPECT keyboard-report Key_E # Report should contain only `E`
+
+RUN 5 ms
+RELEASE M_0
+RUN 1 cycle
+EXPECT keyboard-report empty # Report should be empty
+
+RUN 5 ms
+EXPECT no keyboard-report
+
+# ==============================================================================
+NAME Macro with shift
+
+RUN 5 ms
+PRESS SHIFT
+RUN 1 cycle
+EXPECT keyboard-report Key_LeftShift # Report should contain `shift`
+
+RUN 5 ms
+PRESS M_0
+RUN 1 cycle
+EXPECT keyboard-report Key_RightAlt # Report should contain only `AltGr`
+EXPECT keyboard-report Key_RightAlt Key_7 # Report should contain `AltGr` & `7`
+EXPECT keyboard-report Key_RightAlt # Report should contain only `AltGr`
+EXPECT keyboard-report empty # Report should be empty
+EXPECT keyboard-report Key_LeftShift # Report should contain only `shift`
+EXPECT keyboard-report Key_LeftShift Key_E # Report should contain `shift` & `E`
+
+RUN 5 ms
+RELEASE M_0
+RUN 1 cycle
+EXPECT keyboard-report Key_LeftShift # Report should contain only `shift`
+
+RUN 5 ms
+RELEASE SHIFT
+RUN 1 cycle
+EXPECT keyboard-report empty # Report should be empty
+
+RUN 5 ms
+EXPECT no keyboard-report